이 AppleScript 코드는 최신 버전의 macOS Mojave를 사용하여 작동합니다.

이 코드는 휴지통에있는 모든 항목을 반복하여 각 항목을 원래 위치로 되돌립니다.

휴지통에있는 파일의 원본 소스 폴더가 더 이상 존재하지 않으면 repeat until trashCount is 0명령이 루프를 종료합니다. 휴지통에 남아있는 파일은이 이유로 인해 되돌릴 수없는 파일 만됩니다.

최신 정보

휴지통에서 파일을 다시 가져 오는 프로세스의 반복 루프 중에 데스크탑에서 항목을 선택할 수 있으므로 선택한 데스크탑 항목이 프로세스에 걸리고 휴지통으로 이동 될 수 있습니다. 이 시나리오를 피하기 위해 현재 잠금 해제 된 데스크탑 항목을 잠그고 스크립트 끝에서 잠금을 해제하는 코드를 추가했습니다.

이제 모든 데스크탑 항목이 잠겨 있기 때문에 … 휴지통에서 파일을 되 돌리는 과정에서 어떤 이유로 든 실수로 데스크탑에서 파일 또는 폴더를 선택하고 코드가 선택된 데스크탑 항목을 처리하려고 시도하는 경우 … 항목이 잠겨 있음을 나타내는 대화 상자 창을 생성하고 휴지통으로 계속 보낼 것인지 묻습니다. 스크립트 끝까지 시스템 이벤트 텔 블록은 생성 된 대화 상자를 처리합니다.

property desktopFolder : path to desktop
property unlockedFiles : missing value

tell application "Finder"
    set trashCount to count of every item of trash
    set unlockedFiles to (items of desktopFolder whose locked is false)
    repeat with i in unlockedFiles
        set locked of i to true
    end repeat
end tell

repeat until trashCount is 0
    tell application "Finder" to set orphanCount to count of every item of trash
    putFilesBack()
    tell application "Finder" to set trashCount to count of every item of trash
    if orphanCount is equal to trashCount then exit repeat
end repeat

delay 1

tell application "System Events"
    repeat until not (exists of button "Stop" of scroll area 1 of window 2 of application process "Finder")
        if exists of button "Stop" of scroll area 1 of window 2 of application process "Finder" then
            click button "Stop" of scroll area 1 of window 2 of application process "Finder"
        end if
    end repeat
end tell

tell application "Finder"
    close every Finder window
    delay 1
    repeat with i in unlockedFiles
        set locked of i to false
    end repeat
end tell

on putFilesBack()
    global trashFiles, trashCount, thisItem
    tell application "Finder"
        set trashFiles to every item of trash
        set frontmost to true
        repeat while not frontmost
            delay 0.1
        end repeat
        my closeFinderWindows()
    end tell
    delay 0.1
    tell application "System Events"
        tell application process "Finder"
            repeat with i from 1 to count of trashFiles
                set thisItem to item i of trashFiles
                delay 0.1
                set frontmost to true
                select thisItem
                delay 0.1
                try
                    key code 51 using {command down}
                end try
                delay 0.1
                my closeFinderWindows()
                delay 0.1
            end repeat
        end tell
    end tell
    tell application "Finder" to set trashCount to count of every item of trash
end putFilesBack

on closeFinderWindows()
    tell application "Finder"
        set finderWindowRef to (a reference to (every Finder window whose name is not "Trash"))
        set finderWindowRef to contents of finderWindowRef
        close (items of finderWindowRef)
    end tell
end closeFinderWindows

답변