태그 보관물: microsoft-powerpoint-2016

microsoft-powerpoint-2016

거리가 아닌 셀의 관점에서 그리드를 지정하는 방법은 무엇입니까? 프리젠 테이션을 디자인하는 데 도움이되는 2×3

간격 (PowerPoint 2016에서)이 아닌 표 선의 수를 기준으로 표를 지정할 수 있습니까? 프리젠 테이션을 디자인하는 데 도움이되는 2×3 격자를 원하지만 선 사이의 거리 측면에서 격자를 지정하는 방법 만 찾을 수 있습니다.

내가 찾은 설정 : enter image description here

답변

다음은 내가 유지 관리하는 PowerPoint FAQ 사이트의 코드 예제입니다.

PPT 2013 및 이후 버전의 가이드 작업 http://www.pptfaq.com/FAQ01214-Working-with-Guides-in-PPT-2013-and-later.htm

VBA 작업에 익숙하지 않은 경우 페이지 하단에 간단한 자습서 링크가 있습니다.

이렇게하면 원하는 위치에 horiz / vert 안내선을 추가 할 수 있습니다. 

Sub AddGuides()

    Dim HGuides As String
    Dim VGuides As String
    Dim x As Long
    Dim aGuideArray() As String

    ' Edit these to indicate where you'd like to put guides:
    ' Values are in points, 72 points to the inch
    ' Separate each value from the next with a pipe | character

    ' Horizontal guide positions:
    HGuides = "72|144|256.5"
    ' Vertical guide positions:
    VGuides = "10|20|30|40|50|60|70|80|90|100"

    With ActivePresentation
        ' nb ppHorizonatalGuide = 1; ppVerticalGuide = 2
        ' nb to add guides to master rather than slides,
        '   use .SlideMaster.Guides.Add below
        '   in place of .Guides.Add

        ' First add the horizontal guides
        aGuideArray = Split(HGuides, "|")
        For x = LBound(aGuideArray) To UBound(aGuideArray)
            .Guides.Add ppHorizontalGuide, CSng(aGuideArray(x))
        Next

        ' and now the vertical guides
        aGuideArray = Split(VGuides, "|")
        For x = LBound(aGuideArray) To UBound(aGuideArray)
            .Guides.Add ppVerticalGuide, CSng(aGuideArray(x))
        Next

    End With

End Sub

답변